KT66 Model for PSPICE

I was looking for a KT66 model for PSPICE. The one found on Norman Koren seemed to be cool, but unfortunately, I did not succeed to use it “as is” (syntax errors during simulation). So I have modified a little the way the parameters are passed to SPICE engine (or something like that, I’m certainly not an expert as writing SPICE models !)

Hope it will help some of you …

Anyway, thanks to Norman Koren ! (see great http://www.normankoren.com/Audio/Tubemodspice_article.html)

KT66 SPICE model :

******************
.SUBCKT KT66  1 2 3 4 ; A G2 G1 C (Beam Tetrode)
* M-O Valve Co AKA Genalex
+ PARAMS: MU=11.68 EX=1.197 KG1=510.9 KG2=4500 KP=34 KVB=22.3
+         VCT=0.00 RGI=1000 CCG=16.0p CPG1=2.3p CCP=10.0p
RE1  7 0  1MEG    ; DUMMY SO NODE 7 HAS 2 CONNECTIONS
E1   7 0  VALUE=	; E1 BREAKS UP LONG EQUATION FOR G1.
+{V(2,4)/KP*LOG(1+EXP((1/MU+V(3,4)/V(2,4))*KP))}
G1   1 4  VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1*ATAN(V(1,4)/KVB)}
G2   2 4  VALUE={(EXP(EX*(LOG((V(2,4)/MU)+V(3,4)))))/KG2}
RCP  1 4  1G      ; FOR CONVERGENCE	A  - C
C1   3 4  {CCG}   ; CATHODE-GRID 1	C  - G1
C2   1 3  {CPG1}  ; GRID 1-PLATE	G1 - A
C3   1 4  {CCP}   ; CATHODE-PLATE	A  - C
R1   3 5  {RGI}   ; FOR GRID CURRENT	G1 - 5
D3   5 4  DX      ; FOR GRID CURRENT	5  - C
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS    KT66

Ia = f(Ua) curves from Marconi datasheet :

KT66 Marconi datasheet

PSPICE simulation :

KT66 PSPICE simulation valve tube

Website Pin Facebook Twitter Myspace Friendfeed Technorati del.icio.us Digg Google StumbleUpon Premium Responsive

This entry was posted in Amps. Bookmark the permalink.

Leave a Reply

Your email address will not be published. Required fields are marked *

You may use these HTML tags and attributes: <a href="" title=""> <abbr title=""> <acronym title=""> <b> <blockquote cite=""> <cite> <code> <del datetime=""> <em> <i> <q cite=""> <strike> <strong>